Gradle多模块项目中的配置实践

gradle-practice
├── build.gradle
├── gp-api
│   ├── build.gradle
├── gp-app
│   ├── build.gradle
├── gp-db
│   ├── build.gradle
├── gp-service
│   ├── build.gradle
├── gradle
│   ├── jooq.gradle
│   ├── publish.gradle
│   └── wrapper
├── gradlew
├── gradlew.bat
└── settings.gradle

// config plugin repositories
pluginManagement {
    repositories {
        // aliyun repository for gradle plugin
        maven { url 'https://maven.aliyun.com/repository/gradle-plugin' }
        // default repository
        gradlePluginPortal()
    }
}

// set projects, root dir is root project. Each module is a sub project
rootProject.name = 'gradle-practice'

// include all sub projects. The name is location of the new project in the project hierarchy, for example 'a:b:c', not the file path
// Sub project's default path is the '${rootDir}/${projectName}'.
include 'gp-app'
// use ':' as a separator of project.
include 'gp-api'
include 'gpService'
include 'gp-db'

// Set a custom path for a project
project(':gpService').projectDir = new File(settingsDir, 'gp-service')

/*
为构建脚本引入依赖。
在 「模块 gp-db」 中，我们使用了 jooq 生成代码的 plugin，所以，这里，会先把这个 plugin 的 library 引入进来
 */
buildscript {
    repositories {
        maven { url 'https://maven.aliyun.com/repository/public' }
        mavenCentral()
    }
    dependencies {
        classpath 'nu.studer:gradle-jooq-plugin:4.2'
    }
}

/*
在多模块的项目中，根目录下的 build.gradle 文件，尽量把通用的全局配置都配置到这里
「project」是 gradle 里的核心概念。每个 module 都是一个 project，根目录下是 rootProject
 */
allprojects {
    // 定义所有项目的 group 和 version
    group = 'com.yangxiaochen.gradle.practice'
    version = '1.0.0-SNAPSHOT'

    // 为所有项目引入插件
    apply plugin: 'java'
    apply plugin: 'pmd'

    // 为所有项目
    repositories {
        maven { url 'https://maven.aliyun.com/repository/public' }
        mavenCentral()
    }
    // 定义一些变量
    ext {
        mysqlVersion = '8.0.18'
        jooqVersion = '3.13.1'
        ...
    }
    // 为所有的项目设置依赖
    dependencies {
        pmd 'com.alibaba.p3c:p3c-pmd:1.3.6'
    }
    // Java compiler compile java source file with utf-8 (default gbk in the Windows OS with Simplified Chinese). Java source file must be 'UTF-8'.
    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }
    // Set java compile version
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
}
// Config for every subprojects
subprojects {
    // Project gp-api is a library, it will be published as a sdk lib. So it should define exact dependencies in project's build.gradle file
    // Define spring framework's core dependencies for most projects.
    if (!['gp-api'].contains(project.name)) {
        dependencies {
            // 'implementation platform' define Spring bom
            implementation platform('org.springframework.boot:spring-boot-dependencies:2.1.11.RELEASE')
            implementation platform('org.springframework.cloud:spring-cloud-dependencies:Greenwich.SR3')

            // Spring framework core dependencies
            implementation("org.springframework:spring-context")
            implementation("org.springframework:spring-context-support")
            ...
            // Common utils dependencies
            compileOnly 'org.projectlombok:lombok:1.18.22'
            annotationProcessor 'org.projectlombok:lombok:1.18.22'
            ...
        }
    }
    // Dependency resolve
    configurations {
        all {
            resolutionStrategy {
                force 'com.google.guava:guava:28.2-jre'
            }
            exclude group: 'org.slf4j', module: 'slf4j-log4j12'
        }
    }
}

// 只需额外定义该模块所需的依赖
dependencies {
    implementation 'org.greenrobot:eventbus:3.1.1'
}